Fiddle   tunes   in   ABC   Format

Page 1

If there are tunes, that don't appear on these pages, that you want, my contact information is at the Very bottom of this page and I will try to get your requested tunes on this Page!!!

I also have more pages with ABC formatted tunes near the bottom of this Page...


Tunes in abc Format...

X:1
T:Castle
R:Hornpipe
O:?
M:2/4
C:K.Colbath-Ashley MacIsaac, Buddy MacMaster, Richard Wood
K:A
E|:CEAE CEAE|CEAc ec A2|dcBc defg|aecA BAFA|CEAE CEAE|DFAF DFAF|
EGBG EGBG|A2 AA A3 :|cd|edcd eaga|fedc B2 Bc|dcBc dfef|gfed c2 cd|
eaga faga|ebab gbab|ec'bc' d'efg|a2 aa a2 cd|:ecAE CEAc|fdBG E2 Bc|
dBGE B,EGB|cAEC A,2 cd|ecAc dcdf|agaf fecA|Bcdf eBGB|A2 AA A2 cd:||

X:2
T:Little Donald in the Pigpen
R:Reel
O:?
M:2/2
C:Trad.-John Morris Rankin
K:D
cd|:e2 cA eAcA|Aeec defa|e2 cA eA c2|BABc defa|
e2 cA eAcA|Aeec defa|e2 cA eA c2|BABc defd|
eaaf gfed|eaaf g2 fd|eaaf gfed|cABc defd|
eaaf gfed|eaaf g2 fg|afge faed|BGGd BGBd:||

X:3
T:Jerry's Beaver Hat
R:Jig
O:Ireland
M:6/8
C:Trad.-Ashley MacIsaac
K:D
DFA d2 e|fdB BAF|ABA AFD|EFE E2 E|DFA d2 e|fdB BAF|
ABc dAF|1.EDD D2 D:|2.EDD D3|:A|dfa afd|fbf g2f|
dfa afd|cAe e2 A|dfa afd|fbf gef|ABc dAF|1.EDD D2:|2.EDD D2||

X:4
T:Shandon Bells
R:Jig
O:Ireland
M:6/8
K:D
C:Trad.-Natalie MacMaster, Richard Wood
|:B|AFD DFA|ded cBA|BGE EGB|B2 A Bcd|AFD DFA|ded cBA|
Bcd ecA|1.d3 d2:|2.d3 d||:eg|f2 d dcd|faa aed|cAA eAA|
cde efg|f2 d dcd|fag fed|Bed cBc|1.d3 d:|2.d3 d2||

X:5
T:Rover's Return, O'Reilly's
R:Jig
O:Ireland
M:6/8
C:Trad.-Buddy MacMaster, Ashley MacIsaac, Donny LeBlanc
K:D
|:gf|eAA fed|eAA g2 f|eAA fed|BGG g2 f|
eAA fed|efg a2 g|aba g2 f|dBG G:|
|:AB|A2 a aea|aea aec|Ace agf|gdB GAB|
A2 a aef|gfe a2 f|gag f2 e|dBG G:|
|:gf|ecA fed|ecA A2 f|ecA gfe|dBG Ggf|
ecA fed|ecA A2 f|gag gfe|dBG G:|
|:AB|A2 a aea|aea aec|Ace agf|gdB GAB|
A2 a aef|gfe a2 f|gag f2 e|dBG G:||

X:6
T:West Mabou
R:Reel
O:Cape Breton
M:2/2
C:Trad.-Ashley MacIsaac, Buddy MacMaster
K:G
e|g2 dg e2 dB|g2 dg eaab|g2 dg e2 dB|A2 GA BGGe|
g2 dg e2 db|g2 dg eaag|bgaf gfed|efga babg|
eddB dedB|A2 GA BAAg|eddB dedB|A2 GA BGGg|
eddB dedB|A2 GA BAAe|g2 bg e2 dB|A2 GA BGG||

X:7
T:Smith's Delight
R:Reel
O:Cape Breton?
M:4/4
C:Trad.-Brenda Stubbert
K:D
|:fe|d2 Bd A2 FA|BAFA D2 ED|B,DA,D 1.DFBF|AADF E2:|2.DFBA|FAEA D|
|:fg|afed bafd|Adfd edBd|DFAd 1.FAde|fadf E2:|2.FAdf|eace d2||

X:8
T:Sandy MacIntyre's Trip to Boston
R:Reel
O:Cape Breton
M:4/4
C:John Campbell
K:A
|:F|E2 CE A,ECE|Acef ecce|f2 af ecAc|dBcA BFFA|
E2 CE A,ECE|Acef ecce|F2 af ecBc|dfec A2 A:|
f|eA c2 ecBc|ABce f2 fa|eA c2 ecBc|dfec B2 Bf|
eA c2 ecBc|ABce f2 fg|agfe fgaf|ecBc A2 A:||

X:9
T:Spey in Spate
R:Reel
O:Scotland
M:2/2
C:J.S. Skinner.-Natalie MacMaster
K:D
A,|:D2 FD A,DFA|dcBA ^GAFD|E/2E/2E (3GFE B,EGB|gecA GECE|
DE (3FED A,DFA|dDcD BDAf|gefd ecdB|1.AFGE DA,B,C:|2.AFGE D|:ABc|
d/2d/2d fd AdFA|DFAd fagf|e/2e/2e ge BGED|CEAc egfe|{A}d2 fd  AdFA|
DFAd fagf|gefd ecdB|AFGE D:||



Other links

abc examples: How to figure out the ABC language
Index: Index of Tunes listed on these Pages.
Fiddle tunes in ABC: Page 1...
Fiddle tunes in ABC: Page 2...
Fiddle tunes in ABC: Page 3...
Fiddle tunes in ABC: Page 4...
Back to my Home Page:


This page has been visited times.

Stephen Klein

sk_fidd@hotmail.com
40 Maple Lake Road
Timberlea, Nova Scotia
B3T 1J1
Canada